www.tinc-vpn.org Git - tinc/blob - test/unit/meson.build

   1 dep_cmocka = dependency('cmocka', required: opt_tests)
   2 if not dep_cmocka.found()
   3   subdir_done()
   4 endif
   5
   6 can_wrap = cc.has_link_argument('-Wl,--wrap=func')
   7 if not can_wrap
   8   message('linker has no support for function wrapping, mocked tests will not run')
   9 endif
  10
  11 link_tinc = { 'lib': lib_tinc, 'dep': deps_tinc }
  12 link_tincd = { 'lib': lib_tincd, 'dep': deps_tincd }
  13
  14 # Test definition format:
  15 #
  16 # 'free-form test name': {
  17 #   'code': 'test1.c',      // or ['test1.c', 'test1_util.c']
  18 #   'mock': ['foo', 'bar'], // list of functions to mock (default: empty)
  19 #   'link': link_tinc,      // which binary to link with (default: tincd)
  20 #   'fail': true,           // whether the test should fail (default: false)
  21 # }
  22
  23 tests = {
  24   'dropin': {
  25     'code': 'test_dropin.c',
  26   },
  27   'random': {
  28     'code': 'test_random.c',
  29   },
  30   'random_noinit': {
  31     'code': 'test_random_noinit.c',
  32     'fail': true,
  33   },
  34   'netutl': {
  35     'code': 'test_netutl.c',
  36   },
  37   'net': {
  38     'code': 'test_net.c',
  39     'mock': ['execute_script', 'environment_init', 'environment_exit'],
  40   },
  41   'subnet': {
  42     'code': 'test_subnet.c',
  43   },
  44   'protocol': {
  45     'code': 'test_protocol.c',
  46   },
  47   'utils': {
  48     'code': 'test_utils.c',
  49   },
  50   'splay_tree': {
  51     'code': 'test_splay_tree.c',
  52     'link': link_tinc,
  53   },
  54 }
  55
  56 env = ['CMOCKA_MESSAGE_OUTPUT=TAP']
  57
  58 foreach test, data : tests
  59   args = ld_flags
  60
  61   if can_wrap
  62     mocks = data.get('mock', [])
  63     if mocks.length() > 0
  64       args += ',--wrap='.join(['-Wl'] + mocks)
  65     endif
  66   endif
  67
  68   libs = data.get('link', link_tincd)
  69
  70   exe = executable(test,
  71                    sources: data['code'],
  72                    link_args: args,
  73                    dependencies: [libs['dep'], dep_cmocka],
  74                    link_with: libs['lib'],
  75                    implicit_include_directories: false,
  76                    include_directories: inc_conf,
  77                    build_by_default: false)
  78
  79   must_fail = data.get('fail', false)
  80
  81   test(test,
  82        exe,
  83        suite: 'unit',
  84        timeout: 60,
  85        protocol: must_fail ? 'exitcode' : 'tap',
  86        env: env,
  87        should_fail: must_fail)
  88 endforeach
  89