www.tinc-vpn.org Git - tinc/blob - test/unit/meson.build

   1 dep_cmocka = dependency('cmocka', required: opt_tests)
   2 if not dep_cmocka.found()
   3   subdir_done()
   4 endif
   5
   6 can_wrap = cc.has_link_argument('-Wl,--wrap=func')
   7 if not can_wrap
   8   message('linker has no support for function wrapping, mocked tests will not run')
   9 endif
  10
  11 link_tinc = { 'lib': lib_tinc, 'dep': deps_tinc }
  12 link_tincd = { 'lib': lib_tincd, 'dep': deps_tincd }
  13
  14 # Test definition format:
  15 #
  16 # 'free-form test name': {
  17 #   'code': 'test1.c',      // or ['test1.c', 'test1_util.c']
  18 #   'mock': ['foo', 'bar'], // list of functions to mock (default: empty)
  19 #   'link': link_tinc,      // which binary to link with (default: tincd)
  20 #   'fail': true,           // whether the test should fail (default: false)
  21 # }
  22
  23 tests = {
  24   'random': {
  25     'code': 'test_random.c',
  26   },
  27   'random_noinit': {
  28     'code': 'test_random_noinit.c',
  29     'fail': true,
  30   },
  31   'netutl': {
  32     'code': 'test_netutl.c',
  33   },
  34   'net': {
  35     'code': 'test_net.c',
  36     'mock': ['execute_script', 'environment_init', 'environment_exit'],
  37   },
  38   'subnet': {
  39     'code': 'test_subnet.c',
  40   },
  41   'protocol': {
  42     'code': 'test_protocol.c',
  43   },
  44   'utils': {
  45     'code': 'test_utils.c',
  46   },
  47   'splay_tree': {
  48     'code': 'test_splay_tree.c',
  49     'link': link_tinc,
  50   },
  51 }
  52
  53 env = ['CMOCKA_MESSAGE_OUTPUT=TAP']
  54
  55 foreach test, data : tests
  56   args = ld_flags
  57
  58   if can_wrap
  59     mocks = data.get('mock', [])
  60     if mocks.length() > 0
  61       args += ',--wrap='.join(['-Wl'] + mocks)
  62     endif
  63   endif
  64
  65   libs = data.get('link', link_tincd)
  66
  67   exe = executable(test,
  68                    sources: data['code'],
  69                    link_args: args,
  70                    dependencies: [libs['dep'], dep_cmocka],
  71                    link_with: libs['lib'],
  72                    implicit_include_directories: false,
  73                    include_directories: inc_conf,
  74                    build_by_default: false)
  75
  76   must_fail = data.get('fail', false)
  77
  78   test(test,
  79        exe,
  80        suite: 'unit',
  81        timeout: 60,
  82        protocol: must_fail ? 'exitcode' : 'tap',
  83        env: env,
  84        should_fail: must_fail)
  85 endforeach
  86