www.tinc-vpn.org Git - tinc/blob - test/integration/meson.build

   1 tests = [
   2   'basic.test',
   3   'commandline.test',
   4   'executables.test',
   5   'import-export.test',
   6   'invite-join.test',
   7   'invite-offline.test',
   8   'invite-tinc-up.test',
   9   'security.test',
  10   'security-legacy.test',
  11   'security-sptps.test',
  12   'variables.test',
  13 ]
  14
  15 if opt_crypto != 'nolegacy'
  16   tests += 'algorithms.test'
  17   tests += 'legacy-protocol.test'
  18 endif
  19
  20 if os_name != 'windows'
  21   tests += 'sptps-basic.test'
  22 endif
  23
  24 if os_name == 'linux'
  25   tests += 'ns-ping.test'
  26 endif
  27
  28 if os_name != 'sunos'
  29   tests += 'scripts.test'
  30 endif
  31
  32 exe_splice = executable(
  33   'splice',
  34   sources: 'splice.c',
  35   dependencies: deps_common,
  36   implicit_include_directories: false,
  37   include_directories: inc_conf,
  38   build_by_default: false,
  39 )
  40
  41 env = environment()
  42 env.set('TINC_PATH', exe_tinc.full_path())
  43 env.set('TINCD_PATH', exe_tincd.full_path())
  44 env.set('SPTPS_TEST_PATH', exe_sptps_test.full_path())
  45 env.set('SPTPS_KEYPAIR_PATH', exe_sptps_keypair.full_path())
  46 env.set('SPLICE_PATH', exe_splice.full_path())
  47 env.set('TESTLIB_PATH', meson.current_source_dir() / 'testlib.sh')
  48
  49 deps_test = [
  50   exe_tinc,
  51   exe_tincd,
  52   exe_splice,
  53   exe_sptps_test,
  54   exe_sptps_keypair,
  55 ]
  56
  57 test_wd = meson.current_build_dir()
  58
  59 foreach test_name : tests
  60   target = find_program(test_name, native: true)
  61   test(test_name,
  62        target,
  63        suite: 'integration',
  64        timeout: 5 * 60,
  65        env: env,
  66        depends: deps_test,
  67        workdir: test_wd)
  68 endforeach
  69