www.tinc-vpn.org Git - tinc/blob - src/openssl/meson.build

   1 src_lib_crypto = files(
   2   'cipher.c',
   3   'crypto.c',
   4   'digest.c',
   5   'log.c',
   6   'prf.c',
   7   'rsa.c',
   8   'rsagen.c',
   9 )
  10
  11 # OpenBSD's 'OpenSSL' is actually LibreSSL. pkg-config on OpenBSD 7.0 reports
  12 # it as OpenSSL 1.0, but it has everything we need (unlike 'real' OpenSSL 1.0).
  13
  14 if os_name == 'openbsd'
  15   names = ['openssl', 'eopenssl30', 'eopenssl11']
  16   min_ver = '>=1.0.0'
  17 else
  18   names = ['openssl', 'openssl11']
  19   min_ver = '>=1.1.0'
  20 endif
  21
  22 if meson_version.version_compare('>=0.60')
  23   dep_crypto = dependency(names, version: min_ver, static: static)
  24 else
  25   foreach name : names
  26     dep_crypto = dependency(name, version: min_ver, static: static, required: false)
  27     if dep_crypto.found()
  28       break
  29     endif
  30   endforeach
  31   if not dep_crypto.found()
  32     dep_crypto = dependency('', static: static, fallback: ['openssl', 'openssl_dep'])
  33   endif
  34 endif
  35
  36 cdata.set('HAVE_OPENSSL', 1)
  37