www.tinc-vpn.org Git - tinc/blob - doc/meson.build

   1 man_pages = [
   2   'tinc-gui.8.in',
   3   'tinc.8.in',
   4   'tinc.conf.5.in',
   5   'tincd.8.in',
   6 ]
   7
   8 info_pages = [
   9   'tinc.texi',
  10 ]
  11
  12 info_includes = [
  13   'tincinclude.texi.in',
  14 ]
  15
  16 man_conf = configuration_data()
  17 man_conf.set_quoted('PACKAGE', meson.project_name())
  18 man_conf.set_quoted('VERSION', meson.project_version())
  19 man_conf.set_quoted('localstatedir', dir_local_state)
  20 man_conf.set_quoted('runstatedir', dir_run_state)
  21 man_conf.set_quoted('sysconfdir', dir_sysconf)
  22
  23 foreach man_src : man_pages
  24   man = configure_file(
  25     input: man_src,
  26     output: '@BASENAME@',
  27     configuration: man_conf,
  28   )
  29   install_man(man)
  30 endforeach
  31
  32 prog_makeinfo = find_program('makeinfo', required: opt_docs)
  33 if not prog_makeinfo.found()
  34   subdir_done()
  35 endif
  36
  37 foreach inc : info_includes
  38   configure_file(
  39     input: inc,
  40     output: '@BASENAME@',
  41     configuration: man_conf,
  42   )
  43 endforeach
  44
  45 info_cmd = [
  46   prog_makeinfo,
  47   '-P', '@BUILD_ROOT@/doc',
  48   '@INPUT@',
  49   '--output', '@OUTPUT@',
  50 ]
  51
  52 foreach page : info_pages
  53   custom_target(
  54     'info-page-' + page,
  55     input: page,
  56     output: '@BASENAME@.info',
  57     command: info_cmd,
  58     install: true,
  59     install_dir: dir_info,
  60   )
  61 endforeach
  62