www.tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], [1.0.32])
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AM_INIT_AUTOMAKE([1.11 check-news std-options subdir-objects nostdinc silent-rules -Wall info-in-builddir])
   7 AC_CONFIG_HEADERS([config.h])
   8 AC_CONFIG_MACRO_DIR([m4])
   9 AM_MAINTAINER_MODE
  10 AM_SILENT_RULES([yes])
  11
  12 # Enable GNU extensions.
  13 # Define this here, not in acconfig's @TOP@ section, since definitions
  14 # in the latter don't make it into the configure-time tests.
  15 AC_GNU_SOURCE
  16 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC_C99
  20 AC_PROG_CPP
  21 AC_PROG_INSTALL
  22
  23 AM_PROG_CC_C_O
  24
  25 PKG_PROG_PKG_CONFIG
  26
  27 dnl Check and set OS
  28
  29 AC_CANONICAL_HOST
  30
  31 case $host_os in
  32   *linux*)
  33     linux=true
  34     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  35   ;;
  36   *freebsd*)
  37     bsd=true
  38     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  39   ;;
  40   *darwin*)
  41     bsd=true
  42     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  43   ;;
  44   *solaris*)
  45     solaris=true
  46     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  47   ;;
  48   *openbsd*)
  49     bsd=true
  50     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  51   ;;
  52   *netbsd*)
  53     bsd=true
  54     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  55   ;;
  56   *dragonfly*)
  57     bsd=true
  58     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  59   ;;
  60   *bsd*)
  61     bsd=true
  62     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  63     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  64   ;;
  65   *cygwin*)
  66     cygwin=true
  67     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  68   ;;
  69   *mingw*)
  70     mingw=true
  71     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  72     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  73   ;;
  74   *)
  75     AC_MSG_ERROR("Unknown operating system.")
  76   ;;
  77 esac
  78
  79 AC_ARG_ENABLE(uml,
  80   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  81   [ AS_IF([test "x$enable_uml" = "xyes"],
  82       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  83         uml=true
  84       ],
  85       [uml=false])
  86   ],
  87   [uml=false]
  88 )
  89
  90 AC_ARG_ENABLE(vde,
  91   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  92   [ AS_IF([test "x$enable_vde" = "xyes"],
  93       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  94         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  95         vde=true
  96       ],
  97       [vde=false])
  98   ],
  99   [vde=false]
 100 )
 101
 102 AC_ARG_ENABLE(tunemu,
 103   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 104   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 105       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 106         tunemu=true
 107       ],
 108       [tunemu=false])
 109   ],
 110   [tunemu=false]
 111 )
 112
 113 AC_ARG_WITH(windows2000,
 114   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 115   [ AS_IF([test "x$with_windows2000" = "xyes"],
 116       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 117   ]
 118 )
 119
 120 AC_ARG_WITH([systemdsystemunitdir],
 121      [AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files])],,
 122      [with_systemdsystemunitdir=auto])
 123 AS_IF([test "x$with_systemdsystemunitdir" = "xyes" -o "x$with_systemdsystemunitdir" = "xauto"], [
 124      def_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
 125
 126      AS_IF([test "x$def_systemdsystemunitdir" = "x"],
 127    [AS_IF([test "x$with_systemdsystemunitdir" = "xyes"],
 128     [AC_MSG_ERROR([systemd support requested but pkg-config unable to query systemd package])])
 129     with_systemdsystemunitdir=no],
 130    [with_systemdsystemunitdir="$def_systemdsystemunitdir"])])
 131 AS_IF([test "x$with_systemdsystemunitdir" != "xno"],
 132       [AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])])
 133 AM_CONDITIONAL([HAVE_SYSTEMD], [test "x$with_systemdsystemunitdir" != "xno"])
 134
 135 AM_CONDITIONAL(LINUX, test "$linux" = true)
 136 AM_CONDITIONAL(BSD, test "$bsd" = true)
 137 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 138 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 139 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 140 AM_CONDITIONAL(UML, test "$uml" = true)
 141 AM_CONDITIONAL(VDE, test "$vde" = true)
 142 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 143
 144 AC_CACHE_SAVE
 145
 146 if test -d /sw/include ; then
 147   CPPFLAGS="$CPPFLAGS -I/sw/include"
 148 fi
 149 if test -d /sw/lib ; then
 150   LIBS="$LIBS -L/sw/lib"
 151 fi
 152
 153 dnl Compiler hardening flags
 154 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 155
 156 AX_CFLAGS_WARN_ALL(CFLAGS)
 157
 158 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 159 AS_IF([test "x$enable_hardening" != "xno"],
 160   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 161    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
 162    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"]))
 163    case $host_os in
 164      *mingw*)
 165        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 166        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 167        ;;
 168      *)
 169        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 170        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 171        ;;
 172    esac
 173    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 174    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 175   ]
 176 );
 177
 178 dnl Checks for libraries.
 179
 180 dnl Checks for header files.
 181 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 182
 183 AC_HEADER_STDC
 184 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h time.h sys/uio.h sys/wait.h netdb.h arpa/inet.h arpa/nameser.h dirent.h getopt.h])
 185 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/if_utun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 186   [], [], [#include "$srcdir/src/have.h"]
 187 )
 188 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 189   [], [], [#include "$srcdir/src/have.h"]
 190 )
 191 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 192   [], [], [#include "$srcdir/src/have.h"]
 193 )
 194
 195 dnl Checks for typedefs, structures, and compiler characteristics.
 196 AC_C_CONST
 197 AC_C_VOLATILE
 198 AC_TYPE_PID_T
 199 AC_TYPE_SIZE_T
 200 AC_HEADER_TIME
 201 AC_STRUCT_TM
 202
 203 tinc_ATTRIBUTE(__malloc__)
 204
 205 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 206   [#include "$srcdir/src/have.h"]
 207 )
 208
 209 dnl Checks for library functions.
 210 AC_TYPE_SIGNAL
 211 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall pselect putenv random select strdup strerror strsignal strtol system unsetenv usleep vsyslog writev devname fdevname],
 212   [], [], [#include "$srcdir/src/have.h"]
 213 )
 214
 215 AC_CHECK_FUNC(getopt_long, [getopt=true; AC_DEFINE(HAVE_GETOPT_LONG, 1, [getopt_long()])], [getopt=false])
 216 AM_CONDITIONAL(GETOPT, test "$getopt" = true)
 217
 218 dnl Support for SunOS
 219
 220 AC_CHECK_FUNC(socket, [], [
 221   AC_CHECK_LIB(socket, connect)
 222 ])
 223 AC_CHECK_FUNC(gethostbyname, [], [
 224   AC_CHECK_LIB(nsl, gethostbyname)
 225 ])
 226
 227 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 228   [], [], [#include "$srcdir/src/have.h"]
 229 )
 230
 231 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 232   #include <netinet/in.h>
 233   #include <resolv.h>
 234 ])
 235
 236 AC_CACHE_SAVE
 237
 238 dnl These are defined in files in m4/
 239
 240 tinc_ZLIB
 241 tinc_LZO
 242 tinc_OPENSSL
 243
 244 dnl Check if support for jumbograms is requested
 245 AC_ARG_ENABLE(jumbograms,
 246   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 247   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 248       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 249   ]
 250 )
 251
 252 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile distro/Makefile])
 253
 254 AC_OUTPUT