www.tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], [1.0.26])
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AM_INIT_AUTOMAKE([1.11 check-news std-options subdir-objects nostdinc -Wall])
   7 AC_CONFIG_HEADERS([config.h])
   8 AM_MAINTAINER_MODE
   9
  10 # Enable GNU extensions.
  11 # Define this here, not in acconfig's @TOP@ section, since definitions
  12 # in the latter don't make it into the configure-time tests.
  13 AC_GNU_SOURCE
  14 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC_C99
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20
  21 AM_PROG_CC_C_O
  22
  23 dnl Check and set OS
  24
  25 AC_CANONICAL_HOST
  26
  27 case $host_os in
  28   *linux*)
  29     linux=true
  30     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  31   ;;
  32   *freebsd*)
  33     bsd=true
  34     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  35   ;;
  36   *darwin*)
  37     bsd=true
  38     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  39   ;;
  40   *solaris*)
  41     solaris=true
  42     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  43   ;;
  44   *openbsd*)
  45     bsd=true
  46     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  47   ;;
  48   *netbsd*)
  49     bsd=true
  50     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  51   ;;
  52   *dragonfly*)
  53     bsd=true
  54     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  55   ;;
  56   *bsd*)
  57     bsd=true
  58     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  59     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  60   ;;
  61   *cygwin*)
  62     cygwin=true
  63     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  64   ;;
  65   *mingw*)
  66     mingw=true
  67     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  68     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  69   ;;
  70   *)
  71     AC_MSG_ERROR("Unknown operating system.")
  72   ;;
  73 esac
  74
  75 AC_ARG_ENABLE(uml,
  76   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  77   [ AS_IF([test "x$enable_uml" = "xyes"],
  78       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  79         uml=true
  80       ],
  81       [uml=false])
  82   ],
  83   [uml=false]
  84 )
  85
  86 AC_ARG_ENABLE(vde,
  87   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  88   [ AS_IF([test "x$enable_vde" = "xyes"],
  89       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  90         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  91         vde=true
  92       ],
  93       [vde=false])
  94   ],
  95   [vde=false]
  96 )
  97
  98 AC_ARG_ENABLE(tunemu,
  99   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 100   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 101       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 102         tunemu=true
 103       ],
 104       [tunemu=false])
 105   ],
 106   [tunemu=false]
 107 )
 108
 109 AC_ARG_WITH(windows2000,
 110   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 111   [ AS_IF([test "x$with_windows2000" = "xyes"],
 112       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 113   ]
 114 )
 115
 116 AM_CONDITIONAL(LINUX, test "$linux" = true)
 117 AM_CONDITIONAL(BSD, test "$bsd" = true)
 118 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 119 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 120 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 121 AM_CONDITIONAL(UML, test "$uml" = true)
 122 AM_CONDITIONAL(VDE, test "$vde" = true)
 123 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 124
 125 AC_CACHE_SAVE
 126
 127 if test -d /sw/include ; then
 128   CPPFLAGS="$CPPFLAGS -I/sw/include"
 129 fi
 130 if test -d /sw/lib ; then
 131   LIBS="$LIBS -L/sw/lib"
 132 fi
 133
 134 dnl Compiler hardening flags
 135 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 136
 137 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 138 AS_IF([test "x$enable_hardening" != "xno"],
 139   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 140    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
 141    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"]))
 142    case $host_os in
 143      *mingw*)
 144        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 145        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 146        ;;
 147      *)
 148        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 149        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 150        ;;
 151    esac
 152    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 153    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 154   ]
 155 );
 156
 157 dnl Checks for libraries.
 158
 159 dnl Checks for header files.
 160 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 161
 162 AC_HEADER_STDC
 163 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h time.h sys/uio.h sys/wait.h netdb.h arpa/inet.h arpa/nameser.h dirent.h])
 164 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 165   [], [], [#include "src/have.h"]
 166 )
 167 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 168   [], [], [#include "src/have.h"]
 169 )
 170 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 171   [], [], [#include "src/have.h"]
 172 )
 173
 174 dnl Checks for typedefs, structures, and compiler characteristics.
 175 AC_C_CONST
 176 AC_C_VOLATILE
 177 AC_TYPE_PID_T
 178 AC_TYPE_SIZE_T
 179 AC_HEADER_TIME
 180 AC_STRUCT_TM
 181
 182 tinc_ATTRIBUTE(__malloc__)
 183
 184 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 185   [#include "src/have.h"]
 186 )
 187
 188 dnl Checks for library functions.
 189 AC_TYPE_SIGNAL
 190 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall pselect putenv random select strdup strerror strsignal strtol system unsetenv usleep vsyslog writev],
 191   [], [], [#include "src/have.h"]
 192 )
 193
 194 dnl Support for SunOS
 195
 196 AC_CHECK_FUNC(socket, [], [
 197   AC_CHECK_LIB(socket, connect)
 198 ])
 199 AC_CHECK_FUNC(gethostbyname, [], [
 200   AC_CHECK_LIB(nsl, gethostbyname)
 201 ])
 202
 203 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 204   [], [], [#include "src/have.h"]
 205 )
 206
 207 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 208   #include <netinet/in.h>
 209   #include <resolv.h>
 210 ])
 211
 212 AC_CACHE_SAVE
 213
 214 dnl These are defined in files in m4/
 215
 216 tinc_ZLIB
 217 tinc_LZO
 218 tinc_OPENSSL
 219
 220 dnl Check if support for jumbograms is requested
 221 AC_ARG_ENABLE(jumbograms,
 222   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 223   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 224       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 225   ]
 226 )
 227
 228 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile])
 229
 230 AC_OUTPUT