www.tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], [1.0.23])
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AM_INIT_AUTOMAKE([1.11 check-news std-options subdir-objects nostdinc -Wall])
   7 AC_CONFIG_HEADERS([config.h])
   8 AM_MAINTAINER_MODE
   9
  10 # Enable GNU extensions.
  11 # Define this here, not in acconfig's @TOP@ section, since definitions
  12 # in the latter don't make it into the configure-time tests.
  13 AC_GNU_SOURCE
  14 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC_C99
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20
  21 dnl Check and set OS
  22
  23 AC_CANONICAL_HOST
  24
  25 case $host_os in
  26   *linux*)
  27     linux=true
  28     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  29   ;;
  30   *freebsd*)
  31     bsd=true
  32     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  33   ;;
  34   *darwin*)
  35     bsd=true
  36     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  37   ;;
  38   *solaris*)
  39     solaris=true
  40     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  41   ;;
  42   *openbsd*)
  43     bsd=true
  44     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  45   ;;
  46   *netbsd*)
  47     bsd=true
  48     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  49   ;;
  50   *dragonfly*)
  51     bsd=true
  52     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  53   ;;
  54   *bsd*)
  55     bsd=true
  56     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  57     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  58   ;;
  59   *cygwin*)
  60     cygwin=true
  61     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  62   ;;
  63   *mingw*)
  64     mingw=true
  65     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  66     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  67   ;;
  68   *)
  69     AC_MSG_ERROR("Unknown operating system.")
  70   ;;
  71 esac
  72
  73 AC_ARG_ENABLE(uml,
  74   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  75   [ AS_IF([test "x$enable_uml" = "xyes"],
  76       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  77         uml=true
  78       ],
  79       [uml=false])
  80   ],
  81   [uml=false]
  82 )
  83
  84 AC_ARG_ENABLE(vde,
  85   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  86   [ AS_IF([test "x$enable_vde" = "xyes"],
  87       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  88         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  89         vde=true
  90       ],
  91       [vde=false])
  92   ],
  93   [vde=false]
  94 )
  95
  96 AC_ARG_ENABLE(tunemu,
  97   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
  98   [ AS_IF([test "x$enable_tunemu" = "xyes"],
  99       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 100         tunemu=true
 101       ],
 102       [tunemu=false])
 103   ],
 104   [tunemu=false]
 105 )
 106
 107 AC_ARG_WITH(windows2000,
 108   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 109   [ AS_IF([test "x$with_windows2000" = "xyes"],
 110       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 111   ]
 112 )
 113
 114 AM_CONDITIONAL(LINUX, test "$linux" = true)
 115 AM_CONDITIONAL(BSD, test "$bsd" = true)
 116 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 117 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 118 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 119 AM_CONDITIONAL(UML, test "$uml" = true)
 120 AM_CONDITIONAL(VDE, test "$vde" = true)
 121 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 122
 123 AC_CACHE_SAVE
 124
 125 if test -d /sw/include ; then
 126   CPPFLAGS="$CPPFLAGS -I/sw/include"
 127 fi
 128 if test -d /sw/lib ; then
 129   LIBS="$LIBS -L/sw/lib"
 130 fi
 131
 132 dnl Compiler hardening flags
 133
 134 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 135 AS_IF([test "x$enable_hardening" != "xno"],
 136   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORITFY_SOURCE=2"])
 137    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])
 138    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"])
 139    case $host_os in
 140      *mingw*)
 141        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 142        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 143        # TODO: get -fstack-protector-all working with MinGW
 144        ;;
 145      *)
 146        AX_CHECK_COMPILE_FLAG([-fstack-protector-all], [CPPFLAGS="$CPPFLAGS -fstack-protector-all"])
 147        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 148        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 149        ;;
 150    esac
 151    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 152    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 153   ]
 154 );
 155
 156 dnl Checks for libraries.
 157
 158 dnl Checks for header files.
 159 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 160
 161 AC_HEADER_STDC
 162 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h time.h sys/uio.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 163 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 164   [], [], [#include "src/have.h"]
 165 )
 166 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 167   [], [], [#include "src/have.h"]
 168 )
 169 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 170   [], [], [#include "src/have.h"]
 171 )
 172
 173 dnl Checks for typedefs, structures, and compiler characteristics.
 174 AC_C_CONST
 175 AC_C_VOLATILE
 176 AC_TYPE_PID_T
 177 AC_TYPE_SIZE_T
 178 AC_HEADER_TIME
 179 AC_STRUCT_TM
 180
 181 tinc_ATTRIBUTE(__malloc__)
 182
 183 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 184   [#include "src/have.h"]
 185 )
 186
 187 dnl Checks for library functions.
 188 AC_TYPE_SIGNAL
 189 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall pselect putenv random select strdup strerror strsignal strtol system unsetenv usleep vsyslog writev],
 190   [], [], [#include "src/have.h"]
 191 )
 192
 193 dnl Support for SunOS
 194
 195 AC_CHECK_FUNC(socket, [], [
 196   AC_CHECK_LIB(socket, connect)
 197 ])
 198 AC_CHECK_FUNC(gethostbyname, [], [
 199   AC_CHECK_LIB(nsl, gethostbyname)
 200 ])
 201
 202 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 203   [], [], [#include "src/have.h"]
 204 )
 205
 206 AC_CACHE_SAVE
 207
 208 dnl These are defined in files in m4/
 209
 210 tinc_ZLIB
 211 tinc_LZO
 212 tinc_OPENSSL
 213
 214 dnl Check if support for jumbograms is requested
 215 AC_ARG_ENABLE(jumbograms,
 216   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 217   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 218       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 219   ]
 220 )
 221
 222 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile m4/Makefile])
 223
 224 AC_OUTPUT