www.tinc-vpn.org Git - tinc/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl $Id$
   4
   5 AC_PREREQ(2.61)
   6 AC_INIT
   7 AC_CONFIG_SRCDIR([src/tincd.c])
   8 AM_INIT_AUTOMAKE(tinc, 1.0-cvs)
   9 AC_CONFIG_HEADERS([config.h])
  10 AM_MAINTAINER_MODE
  11
  12 AM_GNU_GETTEXT([external])
  13 AM_GNU_GETTEXT_VERSION(0.14.1)
  14
  15 # Enable GNU extensions.
  16 # Define this here, not in acconfig's @TOP@ section, since definitions
  17 # in the latter don't make it into the configure-time tests.
  18 AC_GNU_SOURCE
  19 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  20
  21 ALL_LINGUAS="nl"
  22
  23 dnl Checks for programs.
  24 AC_PROG_CC_C99
  25 AC_PROG_CPP
  26 AC_PROG_INSTALL
  27 AC_PROG_LN_S
  28 AC_PROG_RANLIB
  29
  30 dnl Check and set OS
  31
  32 #AC_CANONICAL_HOST
  33
  34 case $host_os in
  35   *linux*)
  36     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  37     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  38   ;;
  39   *freebsd*)
  40     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  41     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  42   ;;
  43   *darwin*)
  44     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  45     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  46   ;;
  47   *solaris*)
  48     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  49     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  50   ;;
  51   *openbsd*)
  52     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  53     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  54   ;;
  55   *netbsd*)
  56     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  57     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  58   ;;
  59   *bsd*)
  60     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  61     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  62     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  63   ;;
  64   *cygwin*)
  65     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  66     [ rm -f src/device.c; ln -sf cygwin/device.c src/device.c ]
  67   ;;
  68   *mingw*)
  69     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  70     [ rm -f src/device.c; cp -f src/mingw/device.c src/device.c ]
  71     LIBS="$LIBS -lws2_32"
  72   ;;
  73   *)
  74     AC_MSG_ERROR("Unknown operating system.")
  75   ;;
  76 esac
  77
  78 AC_ARG_ENABLE(tunemu,
  79   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
  80   [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
  81     tunemu=true
  82   ]
  83 )
  84
  85 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
  86
  87 AC_CACHE_SAVE
  88
  89 if test -d /sw/include ; then
  90   CPPFLAGS="$CPPFLAGS -I/sw/include"
  91 fi
  92 if test -d /sw/lib ; then
  93   LIBS="$LIBS -L/sw/lib"
  94 fi
  95
  96 dnl Checks for libraries.
  97
  98 dnl Checks for header files.
  99 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 100
 101 AC_HEADER_STDC
 102 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/socket.h sys/time.h sys/uio.h sys/wait.h netdb.h arpa/inet.h])
 103 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h],
 104   [], [], [#include "have.h"]
 105 )
 106 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 107   [], [], [#include "have.h"]
 108 )
 109 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 110   [], [], [#include "have.h"]
 111 )
 112
 113 dnl Checks for typedefs, structures, and compiler characteristics.
 114 AC_C_CONST
 115 AC_C_VOLATILE
 116 AC_TYPE_PID_T
 117 AC_TYPE_SIZE_T
 118 AC_HEADER_TIME
 119 AC_STRUCT_TM
 120
 121 tinc_ATTRIBUTE(__malloc__)
 122
 123 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 124   [#include "have.h"]
 125 )
 126
 127 dnl Checks for library functions.
 128 AC_FUNC_MEMCMP
 129 AC_FUNC_ALLOCA
 130 AC_TYPE_SIGNAL
 131 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system unsetenv vsyslog writev],
 132   [], [], [#include "have.h"]
 133 )
 134 AC_FUNC_MALLOC
 135 AC_FUNC_REALLOC
 136
 137 dnl Support for SunOS
 138
 139 AC_CHECK_FUNC(socket, [], [
 140   AC_CHECK_LIB(socket, connect)
 141 ])
 142 AC_CHECK_FUNC(gethostbyname, [], [
 143   AC_CHECK_LIB(nsl, gethostbyname)
 144 ])
 145
 146 AC_CHECK_FUNCS([freeaddrinfo gai_strerror getaddrinfo getnameinfo inet_aton],
 147   [], [], [#include "have.h"]
 148 )
 149
 150 AC_CACHE_SAVE
 151
 152 dnl These are defined in files in m4/
 153
 154 tinc_OPENSSL
 155 tinc_ZLIB
 156 tinc_LZO
 157
 158 dnl Check if support for jumbograms is requested
 159 AC_ARG_ENABLE(jumbograms,
 160   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 161   [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ]
 162 )
 163
 164 dnl Check if checkpoint tracing has to be enabled
 165 AC_ARG_ENABLE(tracing,
 166   AS_HELP_STRING([--enable-tracing], [enable checkpoint tracing (debugging only)]),
 167   [ AC_DEFINE(ENABLE_TRACING, 1, [Checkpoint tracing]) ]
 168 )
 169
 170 AC_SUBST(INCLUDES)
 171
 172 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile lib/Makefile po/Makefile.in m4/Makefile])
 173
 174 AC_OUTPUT