www.tinc-vpn.org Git - tinc/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl $Id$
   4
   5 AC_PREREQ(2.59)
   6 AC_INIT
   7 AC_CONFIG_SRCDIR([src/tincd.c])
   8 AM_INIT_AUTOMAKE(tinc, 1.0-cvs)
   9 AC_CONFIG_HEADERS([config.h])
  10 AM_MAINTAINER_MODE
  11
  12 dnl Include the macros from the m4/ directory
  13 AM_ACLOCAL_INCLUDE(m4)
  14
  15 AM_GNU_GETTEXT([external])
  16 AM_GNU_GETTEXT_VERSION(0.12.1)
  17
  18 # Enable GNU extensions.
  19 # Define this here, not in acconfig's @TOP@ section, since definitions
  20 # in the latter don't make it into the configure-time tests.
  21 AC_DEFINE([_GNU_SOURCE], 1, [Enable GNU extenstions])
  22 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  23
  24 ALL_LINGUAS="nl"
  25
  26 dnl Checks for programs.
  27 AC_PROG_CC
  28 AC_PROG_CPP
  29 AC_PROG_GCC_TRADITIONAL
  30 AC_PROG_AWK
  31 AC_PROG_INSTALL
  32 AC_PROG_LN_S
  33 AC_PROG_MAKE_SET
  34 AC_PROG_RANLIB
  35
  36 AC_ISC_POSIX
  37
  38 dnl Check and set OS
  39
  40 #AC_CANONICAL_HOST
  41
  42 case $host_os in
  43   *linux*)
  44     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  45     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  46   ;;
  47   *freebsd*)
  48     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  49     [ rm -f src/device.c; ln -sf freebsd/device.c src/device.c ]
  50   ;;
  51   *darwin*)
  52     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  53     [ rm -f src/device.c; ln -sf darwin/device.c src/device.c ]
  54   ;;
  55   *solaris*)
  56     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  57     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  58   ;;
  59   *openbsd*)
  60     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  61     [ rm -f src/device.c; ln -sf openbsd/device.c src/device.c ]
  62   ;;
  63   *netbsd*)
  64     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  65     [ rm -f src/device.c; ln -sf netbsd/device.c src/device.c ]
  66   ;;
  67   *cygwin*)
  68     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  69     [ rm -f src/device.c; ln -sf cygwin/device.c src/device.c ]
  70   ;;
  71   *mingw*)
  72     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  73     [ rm -f src/device.c; cp -f src/mingw/device.c src/device.c ]
  74     LIBS="$LIBS -lws2_32"
  75   ;;
  76   *)
  77     AC_MSG_ERROR("Unknown operating system.")
  78   ;;
  79 esac
  80
  81 AC_CACHE_SAVE
  82
  83 if test -d /sw/include ; then
  84   CPPFLAGS="$CPPFLAGS -I/sw/include"
  85 fi
  86 if test -d /sw/lib ; then
  87   LIBS="$LIBS -L/sw/lib"
  88 fi
  89
  90 dnl Checks for libraries.
  91
  92 dnl Checks for header files.
  93 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
  94
  95 AC_HEADER_STDC
  96 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/param.h sys/time.h sys/socket.h sys/wait.h sys/mman.h netdb.h arpa/inet.h])
  97 AC_CHECK_HEADERS([net/if.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h],
  98   [], [], [#include "have.h"]
  99 )
 100 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 101   [], [], [#include "have.h"]
 102 )
 103 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 104   [], [], [#include "have.h"]
 105 )
 106
 107 dnl Checks for typedefs, structures, and compiler characteristics.
 108 AC_C_CONST
 109 AC_C_VOLATILE
 110 AC_TYPE_PID_T
 111 AC_TYPE_SIZE_T
 112 AC_HEADER_TIME
 113 AC_STRUCT_TM
 114
 115 tinc_ATTRIBUTE(__malloc__)
 116
 117 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 118   [#include "have.h"]
 119 )
 120
 121 dnl Checks for library functions.
 122 AC_FUNC_MEMCMP
 123 AC_FUNC_ALLOCA
 124 AC_TYPE_SIGNAL
 125 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system unsetenv vsyslog],
 126   [], [], [#include "have.h"]
 127 )
 128 jm_FUNC_MALLOC
 129 jm_FUNC_REALLOC
 130
 131 dnl Support for SunOS
 132
 133 AC_CHECK_FUNC(socket, [], [
 134   AC_CHECK_LIB(socket, connect)
 135 ])
 136 AC_CHECK_FUNC(gethostbyname, [], [
 137   AC_CHECK_LIB(nsl, gethostbyname)
 138 ])
 139
 140 AC_CHECK_FUNCS([freeaddrinfo gai_strerror getaddrinfo getnameinfo inet_aton],
 141   [], [], [#include "have.h"]
 142 )
 143
 144 AC_CACHE_SAVE
 145
 146 dnl These are defined in files in m4/
 147
 148 case $host_os in
 149   *linux*)
 150     tinc_TUNTAP
 151   ;;
 152 esac
 153
 154 tinc_OPENSSL
 155 tinc_ZLIB
 156 tinc_LZO
 157
 158 dnl Check if support for jumbograms is requested
 159 AC_ARG_ENABLE(jumbograms,
 160   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 161   [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ]
 162 )
 163
 164 dnl Check if checkpoint tracing has to be enabled
 165 AC_ARG_ENABLE(tracing,
 166   AS_HELP_STRING([--enable-tracing], [enable checkpoint tracing (debugging only)]),
 167   [ AC_DEFINE(ENABLE_TRACING, 1, [Checkpoint tracing]) ]
 168 )
 169
 170 AC_SUBST(INCLUDES)
 171
 172 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile doc/tincd.8 doc/tinc.conf.5 doc/tincinclude.texi lib/Makefile po/Makefile.in m4/Makefile])
 173
 174 AC_OUTPUT