www.tinc-vpn.org Git - tinc/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl $Id: configure.in,v 1.13.2.48 2002/06/09 15:26:10 zarq Exp $
   4
   5 AC_INIT(src/tincd.c)
   6 AM_INIT_AUTOMAKE(tinc, 1.0-cvs)
   7 AM_CONFIG_HEADER(config.h)
   8
   9 dnl Include the macros from the m4/ directory
  10 AM_ACLOCAL_INCLUDE(m4)
  11
  12 # Enable GNU extensions.
  13 # Define this here, not in acconfig's @TOP@ section, since definitions
  14 # in the latter don't make it into the configure-time tests.
  15 AC_DEFINE([_GNU_SOURCE], [__USE_BSD])
  16
  17 ALL_LINGUAS="nl"
  18
  19 dnl Checks for programs.
  20 AC_PROG_CC
  21 AC_PROG_CPP
  22 AC_PROG_GCC_TRADITIONAL
  23 AC_PROG_AWK
  24 AC_PROG_INSTALL
  25 AC_PROG_LN_S
  26 AC_PROG_MAKE_SET
  27 jm_PERL
  28
  29
  30 AC_ISC_POSIX
  31
  32 dnl Check and set OS
  33
  34 AC_CANONICAL_HOST
  35
  36 case $host_os in
  37   *linux*)
  38     AC_DEFINE(HAVE_LINUX)
  39     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  40   ;;
  41   *freebsd*)
  42     AC_DEFINE(HAVE_FREEBSD)
  43     [ rm -f src/device.c; ln -sf freebsd/device.c src/device.c ]
  44   ;;
  45   *darwin*)
  46     AC_DEFINE(HAVE_FREEBSD)
  47     [ rm -f src/device.c; ln -sf freebsd/device.c src/device.c ]
  48   ;;
  49   *solaris*)
  50     AC_DEFINE(HAVE_SOLARIS)
  51     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  52   ;;
  53   *openbsd*)
  54     AC_DEFINE(HAVE_OPENBSD)
  55     [ rm -f src/device.c; ln -sf openbsd/device.c src/device.c ]
  56   ;;
  57   *netbsd*)
  58     AC_DEFINE(HAVE_NETBSD)
  59     [ rm -f src/device.c; ln -sf netbsd/device.c src/device.c ]
  60   ;;
  61   *)
  62     AC_MSG_ERROR("Unknown operating system.")
  63   ;;
  64 esac
  65
  66 AC_CACHE_SAVE
  67
  68 dnl Checks for libraries.
  69
  70 dnl Checks for header files.
  71 AC_HEADER_STDC
  72 AC_CHECK_HEADERS([fcntl.h inttypes.h limits.h malloc.h stdint.h strings.h syslog.h unistd.h \
  73 net/ethernet.h net/if.h netinet/in_systm.h netinet/ip.h netinet/tcp.h \
  74 sys/file.h sys/ioctl.h sys/param.h sys/time.h])
  75
  76 dnl Checks for typedefs, structures, and compiler characteristics.
  77 AC_C_CONST
  78 AC_TYPE_PID_T
  79 AC_TYPE_SIZE_T
  80 AC_HEADER_TIME
  81 AC_STRUCT_TM
  82
  83 AC_CACHE_CHECK([for socklen_t], ac_cv_type_socklen_t,
  84 [
  85   AC_TRY_COMPILE(
  86   [#include <sys/types.h>
  87   #include <sys/socket.h>],
  88   [socklen_t len = 42; return len;],
  89   ac_cv_type_socklen_t=yes,
  90   ac_cv_type_socklen_t=no)
  91 ])
  92 if test $ac_cv_type_socklen_t = yes; then
  93   AC_DEFINE(HAVE_SOCKLEN_T)
  94 fi
  95
  96 dnl Checks for library functions.
  97 AC_FUNC_MEMCMP
  98 AC_FUNC_ALLOCA
  99 AC_TYPE_SIGNAL
 100 AC_CHECK_FUNCS([asprintf daemon fcloseall flock ftime get_current_dir_name \
 101 putenv select strdup strerror strsignal strtol unsetenv getnameinfo])
 102 jm_FUNC_MALLOC
 103 jm_FUNC_REALLOC
 104
 105 AM_GNU_GETTEXT
 106
 107 dnl Support for SunOS
 108
 109 AC_CHECK_FUNC(socket, [], [
 110   AC_CHECK_LIB(socket, connect)
 111 ])
 112 AC_CHECK_FUNC(gethostbyname, [], [
 113   AC_CHECK_LIB(nsl, gethostbyname)
 114 ])
 115
 116 AC_CACHE_SAVE
 117
 118 dnl These are defined in files in m4/
 119 tinc_TUNTAP
 120 tinc_OPENSSL
 121 tinc_ZLIB
 122
 123 dnl Check if support for jumbograms is requested
 124 AC_ARG_ENABLE(jumbograms,
 125   [  --enable-jumbograms     enable support for jumbograms (packets up to 9000 bytes)],
 126   [ AC_DEFINE(ENABLE_JUMBOGRAMS) ]
 127 )
 128
 129 dnl Check if checkpoint tracing has to be enabled
 130 AC_ARG_ENABLE(tracing,
 131   [  --enable-tracing        enable checkpoint tracing (debugging only)],
 132   [ AC_DEFINE(ENABLE_TRACING) ]
 133 )
 134
 135 AC_SUBST(INCLUDES)
 136
 137 AC_OUTPUT(Makefile
 138 src/Makefile
 139 doc/Makefile
 140 doc/es/Makefile
 141 intl/Makefile
 142 lib/Makefile
 143 m4/Makefile
 144 po/Makefile.in
 145 )