www.tinc-vpn.org Git - tinc/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 dnl $Id: configure.in,v 1.19 2002/04/28 12:46:25 zarq Exp $
   4
   5 AC_INIT(src/tincd.c)
   6 AM_INIT_AUTOMAKE(tinc, 1.0-cvs)
   7 AM_CONFIG_HEADER(config.h)
   8
   9 dnl Include the macros from the m4/ directory
  10 AM_ACLOCAL_INCLUDE(m4)
  11
  12 # Enable GNU extensions.
  13 # Define this here, not in acconfig's @TOP@ section, since definitions
  14 # in the latter don't make it into the configure-time tests.
  15 AC_DEFINE([_GNU_SOURCE], [__USE_BSD])
  16
  17 ALL_LINGUAS="nl"
  18
  19 dnl Checks for programs.
  20 AC_PROG_CC
  21 AC_PROG_CPP
  22 AC_PROG_GCC_TRADITIONAL
  23 AC_PROG_AWK
  24 AC_PROG_INSTALL
  25 AC_PROG_LN_S
  26 AC_PROG_MAKE_SET
  27 jm_PERL
  28
  29
  30 AC_ISC_POSIX
  31
  32 dnl Check and set OS
  33
  34 AC_CANONICAL_HOST
  35
  36 case $host_os in
  37   *linux*)
  38     AC_DEFINE(HAVE_LINUX)
  39     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  40   ;;
  41   *freebsd*)
  42     AC_DEFINE(HAVE_FREEBSD)
  43     [ rm -f src/device.c; ln -sf freebsd/device.c src/device.c ]
  44   ;;
  45   *solaris*)
  46     AC_DEFINE(HAVE_SOLARIS)
  47     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  48   ;;
  49   *openbsd*)
  50     AC_DEFINE(HAVE_OPENBSD)
  51     [ rm -f src/device.c; ln -sf openbsd/device.c src/device.c ]
  52   ;;
  53   *netbsd*)
  54     AC_DEFINE(HAVE_NETBSD)
  55     [ rm -f src/device.c; ln -sf netbsd/device.c src/device.c ]
  56   ;;
  57 esac
  58
  59 AC_CACHE_SAVE
  60
  61 dnl Checks for libraries.
  62
  63 dnl Checks for header files.
  64 AC_HEADER_STDC
  65 AC_CHECK_HEADERS([fcntl.h limits.h sys/ioctl.h syslog.h unistd.h \
  66 sys/time.h malloc.h strings.h sys/file.h])
  67
  68 dnl Checks for typedefs, structures, and compiler characteristics.
  69 AC_C_CONST
  70 AC_TYPE_PID_T
  71 AC_TYPE_SIZE_T
  72 AC_HEADER_TIME
  73 AC_STRUCT_TM
  74
  75 dnl Checks for library functions.
  76 AC_FUNC_MEMCMP
  77 AC_FUNC_ALLOCA
  78 AC_TYPE_SIGNAL
  79 AC_CHECK_FUNCS([ftime socket select strtol strerror flock unsetenv \
  80 asprintf putenv strdup fcloseall daemon strsignal get_current_dir_name])
  81 jm_FUNC_MALLOC
  82 jm_FUNC_REALLOC
  83
  84 AM_GNU_GETTEXT
  85
  86
  87 dnl Support for SunOS
  88
  89 AC_CHECK_FUNC(socket, [], [
  90   AC_CHECK_LIB(socket, connect)
  91 ])
  92 AC_CHECK_FUNC(gethostbyname, [], [
  93   AC_CHECK_LIB(nsl, gethostbyname)
  94 ])
  95
  96 AC_CACHE_SAVE
  97
  98 dnl These are defined in files in m4/
  99 tinc_TUNTAP
 100
 101         use_gcrypt=0
 102         use_openssl=0
 103
 104         AC_ARG_WITH(gcrypt,
 105         [  --with-gcrypt           Use GCRYPT for all cryptographic functions],
 106         [
 107           if test "x$withval" = "xyes" ; then
 108             use_gcrypt=1
 109           else
 110             use_gcrypt=0
 111           fi
 112         ],
 113         [use_gcrypt=0])
 114
 115         AC_ARG_WITH(openssl,
 116         [  --with-openssl          Use OpenSSL for all cryptographic functions],
 117         [
 118           if test "x$withval" = "xyes" ; then
 119             use_openssl=1
 120           else
 121             use_openssl=0
 122           fi
 123         ],
 124         [use_openssl=0])
 125
 126         if test \( $use_gcrypt -eq 0 -a $use_openssl -eq 0 \) \
 127              -o \( $use_gcrypt -eq 1 -a $use_openssl -eq 1 \) ; then
 128           cat << EOM
 129 Error: You must select exactly one of GCRYPT or OpenSSL.
 130 EOM
 131           echo use_openssl=$use_openssl, use_gcrypt=$use_gcrypt
 132           exit 1
 133         fi
 134
 135         if test $use_gcrypt -eq 1 ; then
 136           AC_MSG_RESULT([Selecting GCRYPT for crypto])
 137           tinc_GCRYPT
 138           AC_DEFINE(USE_GCRYPT)
 139         fi
 140         if test $use_openssl -eq 1 ; then
 141           AC_MSG_RESULT([Selecting OpenSSL for crypto])
 142           tinc_OPENSSL
 143           AC_DEFINE(USE_OPENSSL)
 144         fi
 145
 146         tinc_ZLIB
 147
 148 dnl Check if support for jumbograms is requested
 149 AC_ARG_ENABLE(jumbograms,
 150   [  --enable-jumbograms     enable support for jumbograms (packets up to 9000 bytes)],
 151   [ AC_DEFINE(ENABLE_JUMBOGRAMS) ]
 152 )
 153
 154 dnl Check if checkpoint tracing has to be enabled
 155 AC_ARG_ENABLE(tracing,
 156   [  --enable-tracing        enable checkpoint tracing (debugging only)],
 157   [ AC_DEFINE(ENABLE_TRACING) ]
 158 )
 159
 160 AC_SUBST(INCLUDES)
 161
 162 AC_OUTPUT(Makefile
 163 src/Makefile
 164 src/pokey/Makefile
 165 doc/Makefile
 166 doc/es/Makefile
 167 intl/Makefile
 168 lib/Makefile
 169 m4/Makefile
 170 po/Makefile.in
 171 )